FSO ile Klasördeki Resimleri Listeleme ve Sayfalama

Klasik asp ile belirtilen klasördeki resim dosyalarını listeleme ve sayfalama ile ilgili uygulamamız.
<%
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 2
Response.AddHeader "pragma","no-cache"
Response.AddHeader "cache-control","private"
Response.CacheControl = "No-Store"
Response.ContentType = "text/html"
Response.AddHeader "Content-Type", "text/html;charset=UTF-8"
Response.CodePage = 65001
Response.CharSet = "UTF-8"
'#############################################
'Sayfalama (BAŞLANGIÇ)
'#############################################
Function fnSayfalama(byVal strAdres_Satiri, byVal intGecerli_Sayfa, byVal intSayfa_Sayisi)
    Response.Write "<div class=""sayfalama_kapsul"">"
    If Int(intGecerli_Sayfa) =< Int(intSayfa_Sayisi) Then
		intSayfa_Araligi = 2
		
		intSayfa_Alt_Siniri = intGecerli_Sayfa - intSayfa_Araligi
		intSayfa_Ust_Siniri = intGecerli_Sayfa + intSayfa_Araligi
		intSol_Grup_Sayisi = 1 + intSayfa_Araligi
		intSag_Alt_Sinir = intSayfa_Sayisi - intSayfa_Araligi

		If (intSayfa_Ust_Siniri > intSayfa_Sayisi) Then
			intSayfa_Alt_Siniri = intSayfa_Sayisi - (2 * intSayfa_Araligi)
			intSayfa_Ust_Siniri = intSayfa_Sayisi
		End If

		If (intSayfa_Alt_Siniri <= 0) Then
			intSayfa_Alt_Siniri = 1
			intSayfa_Ust_Siniri = intSayfa_Alt_Siniri + (2 * intSayfa_Araligi)
			If intSayfa_Ust_Siniri >= intSayfa_Sayisi Then intSayfa_Ust_Siniri = intSayfa_Sayisi
		End If

		If intSol_Grup_Sayisi >= intSayfa_Alt_Siniri Then intSol_Grup_Sayisi = intSayfa_Alt_Siniri - 1
		
		If intSag_Alt_Sinir <= intSayfa_Ust_Siniri Then intSag_Alt_Sinir = intSayfa_Ust_Siniri + 1

		If intGecerli_Sayfa > 1 Then
            %>
            <a href="<%=strAdres_Satiri%>&gecerli_sayfa=1" title="İlk Sayfa">[««]</a>
            <a href="<%=strAdres_Satiri%>&gecerli_sayfa=<%=intGecerli_Sayfa-1%>" title="Önceki Sayfa">[«]</a>
            <%
		End If

		For i = 1 to intSol_Grup_Sayisi
			If CInt(i) = CInt(intGecerli_Sayfa) Then
				Response.Write "<a title="""&i&". Sayfa"" class=""secili"">"&i&"</a>"
			Else
				Response.Write "<a title="""&i&". Sayfa"" href="""&strAdres_Satiri&"&gecerli_sayfa="&i&""">"&i&"</a>"
			End If
		Next

		If (intSayfa_Alt_Siniri - intSol_Grup_Sayisi > 1 ) Then Response.Write "<a>. . .</a>"

		For i = intSayfa_Alt_Siniri to intSayfa_Ust_Siniri
			If CInt(i) = CInt(intGecerli_Sayfa) Then
				Response.Write "<a title="""&i&". Sayfa"" class=""secili"">"&i&"</a>"
			Else
				Response.Write "<a title="""&i&". Sayfa"" href="""&strAdres_Satiri&"&gecerli_sayfa="&i&""">"&i&"</a>"
			End If
		Next

		If (intSag_Alt_Sinir - intSayfa_Ust_Siniri > 1) Then Response.Write "<a>. . .</a>"

		For i = intSag_Alt_Sinir to intSayfa_Sayisi
			If CInt(i) = CInt(intGecerli_Sayfa) Then
				Response.Write "<a title="""&i&". Sayfa"" class=""secili"">"&i&"</a>"
			Else
				Response.Write "<a title="""&i&". Sayfa"" href="""&strAdres_Satiri&"&gecerli_sayfa="&i&""">"&i&"</a>"
			End If
		Next

		If CInt(intGecerli_Sayfa) <> CInt(intSayfa_Sayisi) Then
        %>
            <a href="<%=strAdres_Satiri%>&gecerli_sayfa=<%=intGecerli_Sayfa+1%>" title="Sonraki Sayfa">[»]</a>
            <a href="<%=strAdres_Satiri%>&gecerli_sayfa=<%=intSayfa_Sayisi%>" title="En Son Sayfa">[»»]</a>
        <%
		End If
    End If
    Response.Write "</div>"
End Function
'#############################################
'Sayfalama (BİTİŞ)
'#############################################

'#############################################
'Zararlı Karakter Temizleme (BAŞLANGIÇ)
'#############################################
Function fnTemizle(parVeri)
	If IsNull(parVeri) Then Exit Function
	parVeri = Replace(parVeri, ">", "")
	parVeri = Replace(parVeri, "<", "")
	parVeri = Replace(parVeri, "'", "")
	parVeri = Replace(parVeri, "*", "")
	parVeri = Replace(parVeri, "%", "")
	fnTemizle = parVeri
End Function
'#############################################
'Zararlı Karakter Temizleme (BİTİŞ)
'#############################################
%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//TR" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html lang="en">
<head>
    <meta http-equiv="content-type" content="text/html; charset=utf-8" />
    <meta name="author" content="www.ontedi.com - Serkan TOGAL" /> 
    <title>Fso ile Resim Listeleme ve Sayfalama - www.ontedi.com</title>
    <style type="text/css">
        *{margin:0px;padding:0px;border:0px;font-size:100%;font:inherit;vertical-align:baseline;border-spacing:0px;}
        body{background:#f2f2f2;color:#000;font-family:"Arial", tahoma, verdana, sans-serif;font-size:13px;}
        .kapsul{width:620px;margin:0px auto;min-height:10px;}
        .resim_liste{list-style-type:none;padding:1px;border:1px solid #abc;margin:2px 2px 2px;float:left;}
        .resim_liste li{float:left;width:200px;height:210px;overflow:hidden;margin:1px;border:1px solid #ccc;}
        .resim_liste li p{padding:0px 2px;width:194px;line-height:20px;height:40px;background:#d1d1d1;margin-bottom:1px;text-align:center;}
        .resim_liste li img{display:block;max-width:180px;margin:0px auto;}
        .sayfalama_kapsul{margin:3px 0px;}
        .sayfalama_kapsul a{display:inline-block;float:left;padding:1px 4px;margin-right:1px;font-size:11px;background:#353C44;color:#fff !important;text-decoration:none;letter-spacing:1px;border-radius:3px;}
        .sayfalama_kapsul a:hover{background:#9A0124;color:#fefefe;}
        .sayfalama_kapsul a.secili{background:#9A0124;color:#fefefe !important;}
        .ontedi{padding:2px 5px;background:#d1d1d1;text-align:center;float:right;border-radius:3px 0px 0px 3px;text-decoration:none;color:#9A0124;}
        .temizleyici{clear:both;}
    </style>
</head>
<body>
    <!-- .kapsul (BAŞLANGIÇ) -->
    <div class="kapsul">
        <%
        intIcerik_Sayisi = 3
        intGecerli_Sayfa = fnTemizle(Trim(Request.QueryString("gecerli_sayfa")))
        If intGecerli_Sayfa = "" OR IsNumeric(intGecerli_Sayfa) = False Then
	        intGecerli_Sayfa = CInt(1)
        Else
	        intGecerli_Sayfa = CInt(Abs(intGecerli_Sayfa))
        End If

        strListelenecek_Klasor = "galeri/"

        Set fso = Server.CreateObject("Scripting.FileSystemObject")
        Set arrDosyalar = fso.GetFolder(Server.MapPath(strListelenecek_Klasor))
        intResim_Sayisi = arrDosyalar.Files.Count
        If intResim_Sayisi > 0 Then
            i = 1
            intSayfa_Sayisi = intResim_Sayisi/intIcerik_Sayisi
            if InStr(1, intSayfa_Sayisi, ",") > 0 Then
                intSayfa_Sayisi = Int(intSayfa_Sayisi) + 1
            Else
                intSayfa_Sayisi = intSayfa_Sayisi
            End If              
            intSayfa_Baslangic = (intGecerli_Sayfa - 1) * intIcerik_Sayisi
            intSayfa_Bitis = (intGecerli_Sayfa) * intIcerik_Sayisi
            %>
            <ul class="resim_liste">
            <%
	        For Each strDosya In arrDosyalar.Files
		        If ((intSayfa_Baslangic < i) AND (i =< intSayfa_Bitis)) Then
			        %>
				        <li>
					        <p>Dosya Adı: <%=strDosya.Name%><br />Dosya Boyutu: <%=strDosya.Size%> bayt</p>
					        <img src="<%=strListelenecek_Klasor%><%=strDosya.Name%>" alt="" />
				        </li>
			        <%
		        End If
		        i = i + 1
	        Next
            %>
            </ul>
            <div class="temizleyici"></div>
            <%
	        strAdres_Satiri = "?islem="&strIslem&""
	        Response.Write fnSayfalama(strAdres_Satiri, intGecerli_Sayfa, intSayfa_Sayisi)
        End If
        %>
        <a class="ontedi" href="http://www.ontedi.com" target="_blank">ontedi.com</a>
    </div>
    <!-- .kapsul (BİTİŞ) -->
</body>
</html>
FSO ile Klasördeki Resimleri Listeleme ve Sayfalama

Yorumlar

Yorum Yaz

REKLAM

REKLAM

REKLAM

EN
